Code                 ;################################# 
; Configuration aliases 
;################################# 
;This line allows you to change the logo and the nicknames color 
alias -l kikunetlogo return $+($chr(91),$chr(31),$chr(3),07,NetSplit,$chr(3),$chr(31),$chr(93),$chr(3),14) 
;Allows to choose the symbol that separates nicks (use //echo - ag $asc($$?) to have the number of the symbol. Example here the symbol is "," so its code is 44) 
alias -l kikunetcharsep return $chr(44) 44 
;Allows you to choose the number of nickname displayed on one line 
alias -l kikunetmaxnick return 20 

alias -l safe return $!decode( $encode($1-, m) ,m) 

on ^*:quit:{ 
  var %b $comchan($nick,0) 
  while %b { 
    if $0 == 2 && $count($1,.) > 0 && $count($2,.) > 0 { 
      hadd -m $comchan($nick,%b) $nick $1- 
      $+(.timerkikunet,$cid,$comchan($nick,%b)) -h 1 3000 kikunetlook $safe($comchan($nick,%b)) $(|) hfree $safe($comchan($nick,%b)) 
    } 
    else { 
      if ($nick == $me) echo -t $comchan($nick,%b) [Çıkış] Tu quittes ce serveur : $1- 
      else echo -t $comchan($nick,%b) [Çıkış] $nick $gettok($fulladdress,2,33) $1- [ $+ $calc($nick($comchan($nick,%b),0) - 1) Kişi] 
    } 
    dec %b 
  } 
  if ($query($nick)) echo -t $query($nick) [Çıkış] $nick $address($nick,2) $1- 
  haltdef 
} 
alias -l kikunetlook { 
  var %i 1,%max $hget($1,0).item 
  while %i <= %max { 
    var %txt $+(%txt,$gettok($kikunetcharsep,1,32),$hget($1,%i).item) 
    inc %i 
    if $numtok(%txt,$gettok($kikunetcharsep,2,32)) >= $kikunetmaxnick || !$hget($1,%i).item { echo -t $1 %netcolor $sorttok($mid(%txt,2-),$gettok($kikunetcharsep,2,32)) $iif(%max == 1,$hget($1,%max).data) | unset %txt } 
  } 
  if ($hget($1) && %max > 1) echo -t $1 %netcolor %max $+(personne,$iif(%max > 1,s)) $+(perdue,$iif(%max > 1,s)) $hget($1,%max).data 
}